mirror of
https://github.com/mumble-voip/mumble.git
synced 2025-10-26 11:19:16 +00:00
5cffbf3bd3
This commit changes various pri and pro files to always prepend the global build output directory (which can be either 'release' or 'debug', depending on the current build configuration). Otherwise, if a library that we build ourselves, such as -lspeex in CONFIG+=bundled-speex, is also available in one of the other lib dirs, we can't be sure that the one in our build output directory will be used. This is a problem on FreeBSD, where we add /usr/local/lib to the QMAKE_LIBDIR in compiler.pri. That directory might contain its own -lspeex. With this change, we now prefer libraries in our build output directory to system libraries.
79 lines
2.2 KiB
Prolog
79 lines
2.2 KiB
Prolog
# Copyright 2005-2016 The Mumble Developers. All rights reserved.
|
|
# Use of this source code is governed by a BSD-style license
|
|
# that can be found in the LICENSE file at the root of the
|
|
# Mumble source tree or at <https://www.mumble.info/LICENSE>.
|
|
|
|
include (../compiler.pri)
|
|
|
|
VERSION = 1.3.0
|
|
TARGET_EXT = .dll
|
|
TEMPLATE = lib
|
|
CONFIG -= qt
|
|
CONFIG *= dll shared debug_and_release warn_on
|
|
CONFIG -= embed_manifest_dll
|
|
TARGET = mumble_ol
|
|
RC_FILE = mumble_ol.rc
|
|
SOURCES = lib.cpp d3d9.cpp dxgi.cpp d3d10.cpp d3d11.cpp ods.cpp opengl.cpp HardHook.cpp D11StateBlock.cpp
|
|
HEADERS = lib.h ods.h HardHook.h overlay_blacklist.h D11StateBlock.h ../3rdparty/GL/glext.h
|
|
EFFECTS = overlay.fx
|
|
DX11_PIXEL_SHADERS = overlay11.ps
|
|
DX11_VERTEX_SHADERS = overlay11.vs
|
|
DIST = overlay.h overlay.fx HardHook.h
|
|
|
|
DEFINES -= UNICODE
|
|
|
|
QMAKE_CXXFLAGS_RELEASE -= -MD
|
|
QMAKE_CXXFLAGS_DEBUG -= -MDd
|
|
|
|
QMAKE_CXXFLAGS_RELEASE *= -MT
|
|
QMAKE_CXXFLAGS_DEBUG *= -MTd
|
|
|
|
LIBS *= -ldxguid -luuid -lole32 -luser32 -ladvapi32
|
|
LIBS *= -ld3d9 -ld3d10 -ld3d11 -ld3dcompiler -ldxgi
|
|
|
|
CONFIG(force-x86_64-toolchain) {
|
|
DEFINES += USE_MINHOOK
|
|
INCLUDEPATH *= ../3rdparty/minhook-src/include
|
|
LIBS *= -lminhook
|
|
}
|
|
|
|
CONFIG(release, debug|release) {
|
|
DESTDIR = ../release
|
|
QMAKE_LIBDIR = ../release $$QMAKE_LIBDIR
|
|
}
|
|
|
|
CONFIG(debug, debug|release) {
|
|
DESTDIR = ../debug
|
|
QMAKE_LIBDIR = ../debug $$QMAKE_LIBDIR
|
|
DEFINES *= DEBUG
|
|
}
|
|
|
|
# Override fxc binary for the x86 build.
|
|
CONFIG(force-x86-toolchain) {
|
|
exists($$DXSDK_DIR) {
|
|
FXC = "\"$$(DXSDK_DIR)\\Utilities\\bin\\x86\\fxc.exe\""
|
|
} else {
|
|
FXC = fxc.exe
|
|
}
|
|
} else {
|
|
FXC = fxc.exe
|
|
}
|
|
|
|
fxc.output = ${QMAKE_FILE_BASE}.hex
|
|
fxc.commands = $${FXC} /Tfx_4_0 /O3 /Fh${QMAKE_FILE_OUT} ${QMAKE_FILE_NAME}
|
|
fxc.input = EFFECTS
|
|
fxc.CONFIG *= no_link target_predeps
|
|
QMAKE_EXTRA_COMPILERS *= fxc
|
|
|
|
vs11.output = ${QMAKE_FILE_BASE}.ps.h
|
|
vs11.commands = $${FXC} /Tvs_5_0 /O3 /Vng_vertex_shader /Fh${QMAKE_FILE_OUT} ${QMAKE_FILE_NAME}
|
|
vs11.input = DX11_VERTEX_SHADERS
|
|
vs11.CONFIG *= no_link target_predeps
|
|
QMAKE_EXTRA_COMPILERS *= vs11
|
|
|
|
ps11.output = ${QMAKE_FILE_BASE}.vs.h
|
|
ps11.commands = $${FXC} /Tps_5_0 /O3 /Vng_pixel_shader /Fh${QMAKE_FILE_OUT} ${QMAKE_FILE_NAME}
|
|
ps11.input = DX11_PIXEL_SHADERS
|
|
ps11.CONFIG *= no_link target_predeps
|
|
QMAKE_EXTRA_COMPILERS *= ps11
|