mirror of
https://github.com/mumble-voip/mumble.git
synced 2025-10-26 11:19:16 +00:00
d55d944ebc
The g15helper program is currently coded against Logitech's legacy G15 SDK. Logitech's newer SDK, which is the only one shipped in their newer versions of Logitech Gaming Software, is not compatible. For OS X, the legacy SDK is still available for download if you download the version of LGS (GamePanel 3.x) that supports OS X 10.4 through 10.6. However, the SDK shipped in this version of their software uses slightly different paths than we expect. This commit changes the paths to make sense with the SDK shipped with the GamePanel 3.x software.
75 lines
1.4 KiB
Prolog
75 lines
1.4 KiB
Prolog
TEMPLATE = subdirs
|
|
CONFIG *= ordered debug_and_release
|
|
|
|
!CONFIG(no-client) {
|
|
unix:!CONFIG(bundled-speex):system(pkg-config --atleast-version=1.2 speexdsp) {
|
|
CONFIG *= no-bundled-speex
|
|
}
|
|
!CONFIG(no-bundled-speex) {
|
|
SUBDIRS *= speexbuild
|
|
}
|
|
|
|
CONFIG(sbcelt) {
|
|
SUBDIRS *= celt-0.7.0-build sbcelt-lib-build sbcelt-helper-build
|
|
} else {
|
|
unix:!CONFIG(bundled-celt):system(pkg-config --atleast-version=0.7.0 celt) {
|
|
CONFIG *= no-bundled-celt
|
|
}
|
|
!CONFIG(no-bundled-celt) {
|
|
SUBDIRS *= celt-0.7.0-build celt-0.11.0-build
|
|
}
|
|
}
|
|
|
|
!CONFIG(no-opus) {
|
|
CONFIG *= opus
|
|
}
|
|
|
|
CONFIG(opus):!CONFIG(no-bundled-opus) {
|
|
SUBDIRS *= opus-build
|
|
}
|
|
|
|
SUBDIRS *= src/mumble
|
|
|
|
win32:CONFIG(static) {
|
|
SUBDIRS *= src/mumble_exe
|
|
}
|
|
|
|
!CONFIG(no-plugins) {
|
|
SUBDIRS *= plugins
|
|
}
|
|
|
|
win32 {
|
|
SUBDIRS *= 3rdparty/fx11-build
|
|
SUBDIRS *= overlay
|
|
!CONFIG(no-g15) {
|
|
SUBDIRS *= g15helper
|
|
}
|
|
}
|
|
|
|
unix:!macx:!CONFIG(no-overlay) {
|
|
SUBDIRS *= overlay_gl
|
|
}
|
|
|
|
macx {
|
|
MUMBLE_PREFIX = $$(MUMBLE_PREFIX)
|
|
isEmpty(MUMBLE_PREFIX) {
|
|
error("Missing $MUMBLE_PREFIX environment variable");
|
|
}
|
|
SUBDIRS *= macx
|
|
!exists($$(MUMBLE_PREFIX)/../LCDSDK) {
|
|
CONFIG *= no-g15
|
|
}
|
|
!CONFIG(no-g15) {
|
|
SUBDIRS *= g15helper
|
|
}
|
|
}
|
|
}
|
|
|
|
!CONFIG(no-server) {
|
|
SUBDIRS *= src/murmur
|
|
}
|
|
|
|
DIST=LICENSE INSTALL README README.Linux CHANGES
|
|
|
|
include(scripts/scripts.pro)
|